Mirror of forum.nim-lang.org

7619 :: Why I can't unmarshal JSON with spaces in the JSON keys?

• hronro (orginal) [2021-03-13T11:58:26+01:00] view original

  Why I can't unmarshal JSON with spaces in the JSON keys?

  import json
  
  type
    FooBar = object
      `Foo Bar`: string
  
  const jsonString = "{\"Foo Bar\": \"Hello World\"}"
  
  let foobar = to(parseJson(jsonString), FooBar)
  Run

  Nim Playground

  Is this a bug of Nim or am I missed something?

---

• shirleyquirk (orginal) [2021-03-13T13:01:05+01:00] view original

  interesting, it's that Foo Bar is not the internal name for that member, it gets converted to FooBar

  type
    Foo = object
      `Foo Bar`: string
      #FooBar: string # error attempt to redefine FooBar
  
  var x:Foo
  x.FooBar = "world"
  assert x.FooBar = "world"
  Run

  so it's impossible to unpack a field containing a space to an object.

---

• juancarlospaco (orginal) [2021-03-13T14:09:19+01:00] view original

  https://play.nim-lang.org/#ix=2SFI

  Because

  `Foo Bar`
  Run

  is FooBar

---

• shirleyquirk (orginal) [2021-03-13T17:30:35+01:00] view original

  you could use a Table[string,string] instead

  import json,tables
  
  const jsonString = "{\"Foo Bar\": \"Hello World\"}"
  
  let foobar = to(parseJson(jsonString), Table[string,string])
  assert foobar["Foo Bar"] == "Hello World"
  Run

---

• Yardanico (orginal) [2021-03-13T19:38:48+01:00] view original

  Your answer is good, but it's missing the case if we don't have a pure string-string mapping. In that case, we can do it this way:

  import json,tables
  
  const jsonString = "{\"Foo Bar\": \"Hello World\"}"
  
  let foobar = to(parseJson(jsonString), Table[string,JsonNode])
  doAssert foobar["Foo Bar"].getStr() == "Hello World"
  Run

---

• treeform (orginal) [2021-03-14T07:53:59+01:00] view original

  Jsony with a rename hook:

  import jsony
  
  type
    FooBar = object
      `Foo Bar`: string
  
  const jsonString = "{\"Foo Bar\": \"Hello World\"}"
  
  proc renameHook*(v: var FooBar, fieldName: var string) =
    if fieldName == "Foo Bar":
      fieldName = "FooBar"
  
  echo jsonString.fromJson(FooBar)
  Run

  Jsony is a very fast json parser with hooks https://github.com/treeform/jsony

---