Mirror of forum.nim-lang.org

10408 :: How to echo distinct type

• IvanS (orginal) [2023-08-14T20:55:41+02:00] view original

  I'm using autome for hotkeys, but for debugging I want to be able to check things with echo, but the compiler throws an error.

  in autome Hotkey is defined as "distinct int" but when I want to display a 'Hotkey' variable I get Error: type mismatch: got <Hotkey> but expected one of:

  proc echo(x: varargs[typed, $])

  first type mismatch at position: 1 required type for x: varargs[typed] but expression 'hotkeyNext' is of type: Hotkey

---

• termer (orginal) [2023-08-14T20:59:32+02:00] view original

  Use int(myVar) or myVar.int to get it as a normal int

---

• namisboss (orginal) [2023-08-14T21:59:09+02:00] view original

  As Termer said you can convert myVar back to an int to print it. Alternatively you can define your own proc that converts it to text:

  
  proc `$`(a: Hotkey): string =
    return "Value: " & $int(a)
  Run

  The way varargs works is that it assumes each arg is a string and if not applies $(arg) to try to convert it to a string.

---

• ElegantBeef (orginal) [2023-08-14T22:50:08+02:00] view original

  Minor pedantic correction "the way varargs[string, $] works" :P

---

• awr1 (orginal) [2023-08-14T22:52:52+02:00] view original

  you can borrow like so:

  type Foo = distinct int
  proc `$`(x: Foo): string {.borrow.}
  
  echo (Foo 1)
  Run

  also, instead of borrowing, you can use distinctBase for weird type-general nonsense:

  import std / typetraits
  
  type
    Foo = distinct int
    Bar = distinct float
  
  type Distinctable = concept x
    x is distinct
  
  proc `$`[T: Distinctable](x: T): string = $T & '(' & $(T.distinctBase)(x) & ')'
  
  echo (Foo 1)
  echo (Bar 2'f)
  Run

---

• termer (orginal) [2023-08-14T23:28:17+02:00] view original

  What does {.borrow.} do? Is it like lent?

---

• awr1 (orginal) [2023-08-15T00:03:19+02:00] view original

  entirely unrelated. it's specifically for extending procedures from a base type to a distinct type

---

• choltreppe (orginal) [2023-08-15T07:46:54+02:00] view original

  You dont need the concept. You can just directly use the typeclass distinct

  proc `$`[T: distinct](x: T): string = $T & '(' & $(T.distinctBase)(x) & ')'
  Run

---