Mirror of forum.nim-lang.org

9462 :: Custom macro for if-let statement

• drkameleon (orginal) [2022-09-13T16:52:25+02:00] view original

  I have many (many) instances where I have something like this:

  
  if (let aVar = getVar("var"); aVar != VNULL) {
     # do sth
  Run

  I'm trying to replace this with something more concise (preferrably a macro, which I believe it should work) to avoid all this visual clutter.

  E.g.:

  
  if (checkVar("var")) {
      # do sth with aVar here
  Run

  This means that the macro should be able to perform the check and declare the variable with a custom name (a + capitalized var-name, in this case).

  This is what I've come up with:

  
  macro checkVar(name: untyped): untyped =
      let varName =  ident('a' & ($name).capitalizeAscii())
      result = quote do:
          (let `varName` = getVar(`name`); `varName` != VNULL)
  Run

  Do you see anything wrong? (It seems to be working, but given that I'm not too familiar with Nim's macros, I'm still not sure...)

---

• planetis (orginal) [2022-09-13T17:53:12+02:00] view original

  You don't need a macro a template works fine, I personally use an operator:

  
  template `?=`(name, value): bool = (let name = value; name != invalidId)
  Run

---

• blashyrk92 (orginal) [2022-09-13T18:06:05+02:00] view original

  Or if you wanna do it with a macro still, you could do something like this:

  
  macro checkVar(name: untyped, body: untyped): untyped =
      let varName =  ident('a' & ($name).capitalizeAscii())
      result = quote do:
          if (let `varName` = getVar(`name`); `varName` != VNULL):
              `body`
  
  checkVar("kek"):
      # this body is executed only if `getVar` returns something other than VNULL
      # aKek is defined in this body
      echo aKek
  Run

---

• drkameleon (orginal) [2022-09-13T18:07:02+02:00] view original

  Thanks a lot! I'll give it a try :)

  P.S. Χαιρετισμούς από Ισπανία!

---

• PMunch (orginal) [2022-09-14T14:12:49+02:00] view original

  By the way, you don't need to capitalize it. Remember Nim is case and underscore insensitive, so avar is the same as aVar and aVAR.

---

• zAz (orginal) [2024-09-23T10:57:34+02:00] view original

  Maybe:

  
  import std/[options, macros]
  
  macro someTo(optionValue, varDefOrName: untyped): untyped =
    let isVarDef = varDefOrName.kind == nnkVarTy
    let varName = if isVarDef: varDefOrName[0] else: varDefOrName
    
    let tempVarName = genSym(nskLet, "temp")
    let okVarName = genSym(nskLet, "ok")
    
    result = quote do:
      let `okVarName` = `optionValue`.isSome
      let `tempVarName` = if `okVarName`: `optionValue`.get else: default(typeof(`optionValue`.get))
      
      when `isVarDef`:
        var `varName` {.inject.} = `tempVarName`
      else:
        let `varName` {.inject.} = `tempVarName`
      
      `okVarName`
  
  # Example usage
  var a = "test".some
  
  # when we want var
  if a.someTo(var d):
    echo "a has a value: ", d
    d = "test2"
  else:
    echo "a is def(T)"
  
  # when we want let
  if a.someTo(e):
    echo "a has a value: ", e
    #e = "test2"
  else:
    echo "a is def(T)"
  Run

---