Mirror of forum.nim-lang.org

4632 :: Is there a way to make kind of like an override named block?

• treeform (orginal) [2019-02-06T23:25:45+01:00] view original

  I would like to have some thing like this override/section thingy bellow:

  If I have just a section named "redbox" I just want it to act normally with no substitution:

  section "redbox":
    echo "boring stuff"
  Run

  But if I have an override block, some where in the code.

  override "redbox":
    echo "this is great!"
  
  section "redbox":
    echo "boring stuff"
  Run

  It would instead use whats in the override

  Pseudocode kind of:

  var overrides = newTable[name, untyped]()
  template override(name: string, inner: untyped) =
    overrides[name] = inner
  
  template section(name: string, inner: untyped) =
    if name in overrides:
      overrides[name]
    else:
      inner
  Run

  How can I make it happen with nim?

---

• solo989 (orginal) [2019-02-07T00:03:58+01:00] view original

  This essentially does what you want.

  template override(a, b : untyped) : untyped =
    template a() : untyped =
      b
  
  template section(a, b : untyped) : untyped =
    when compiles(a()):
      a()
    else:
      b
  
  override redbox:
    echo "this is great!"
  
  section redbox:
    echo "boring stuff"
  
  section whatever:
    echo "boring stuff2"
  Run

  As a side effect it creates templates though. So you could call redbox like

  redbox()
  Run

---

• solo989 (orginal) [2019-02-07T03:42:57+01:00] view original

  I thought of another way to solve that doesn't produce side effect templates.

  import macros
  import tables
  
  var overrides {.compiletime.} = initTable[string,string]()
  macro override(a, b: untyped) : untyped =
    var x = genSym(nskTemplate)
    overrides[a.strVal] = x.strVal
    result = quote do:
      template `x`() : untyped =
        `b`
  
  macro section(a, b : untyped) : untyped =
    let aStr = a.strVal
    if aStr in overrides:
      let templateName = ident(overrides[aStr])
      result = quote do:
        `templateName`()
    else:
      result = b
  
  
  
  
  override redbox:
    echo "Hello"
  
  section redbox:
    echo "Goodbye"
  
  section whatever:
    echo "Hello World!"
  Run

---

• treeform (orginal) [2019-02-07T03:48:53+01:00] view original

  Wow this is great. I really like the two approaches you made. Thank you!

---

• treeform (orginal) [2019-02-13T00:50:14+01:00] view original

  Do you know if I can make it work with strings? Some how to turn string into a symbol in a template?

  template override(a: string, b : untyped) : untyped =
    template {a cast from string}() : untyped =
      echo a
      b
  
  template section(a, b : untyped) : untyped =
    when compiles({a cast from string}()):
      a()
    else:
      echo a
      b
  
  override "redbox":
    echo "Hello"
  
  section "redbox":
    echo "Goodbye"
  
  section "whatever":
    echo "Hello World!"
  Run

---

• solo989 (orginal) [2019-02-13T02:30:09+01:00] view original

  Now with string.

  import macros
  import tables
  
  var overrides {.compiletime.} = initTable[string,string]()
  macro override(aStr : static[string], b: untyped) : untyped =
    var x = genSym(nskTemplate)
    overrides[aStr] = x.strVal
    result = quote do:
      template `x`() : untyped =
        `b`
  
  macro section(aStr : static[string], b : untyped) : untyped =
    if aStr in overrides:
      let templateName = ident(overrides[aStr])
      result = quote do:
        `templateName`()
    else:
      result = b
  
  
  
  
  override "redbox":
    echo "Hello"
  
  section "redbox":
    echo "Goodbye"
  
  section "whatever":
    echo "Hello World!"
  Run

---