Mirror of forum.nim-lang.org

10551 :: How to echo from a proc correctly?

• Cleversn (orginal) [2023-10-17T03:18:07+02:00] view original

  Hi, beginner here. Consider the following code:

  
  import winim
  
  let myRange = 0..99
  
  proc playAndWriteLN(audioFile, myStr: string) =
    # PlaySound is a procedure from the winim package, available on Windows only
    PlaySound(audioFile, 0, SND_NOSTOP)
    echo(myStr)
  Run

  this works as long as I pass a single string to be written by echo, e.g.:

  
  playAndWriteLN("C:/winvox/Sound/Sortevox/So_sorte.wav", "The range is that one.")
  Run

  But it stops working as soon as I want to pass more than one parameter to echo, e.g.

  
  playAndWriteLN("C:/winvox/Sound/Sortevox/So_sorte.wav", "The range is between ", myRange.a, " and ", myRange.b)
  Run

  How do I solve this? I tried the following at playAndWriteLN signature:

  
  proc playAndWriteLN(audioFile: string; myStr: varargs[string, `$`]) =
  Run

  Then it works, except that it prints quotes and brackets to the screen. How can I command it to print like a normal echo, one that is outside any procedure?

  thanks much.

---

• xigoi (orginal) [2023-10-17T06:31:09+02:00] view original

  import std/strutils
  proc playAndWriteLN(audioFile, myStr: varargs[string, `$`]) =
    # PlaySound(audioFile, 0, SND_NOSTOP)
    echo(myStr.join)
    playAndWriteLN("The range is between ", 0, " and ", 99)
  Run

  (the forum doesn't like my formatting today for some reason)

---

• Araq (orginal) [2023-10-17T06:37:05+02:00] view original

  Try:

  proc playAndWriteLN(audioFile: string; myStr: varargs[typed, `$`]) =
  
  Run

  But maybe this then needs to become a macro, not sure right now.

---

• ingo (orginal) [2023-10-17T07:24:37+02:00] view original

  format the string at its source and pass it as one whole thing? https://nim-lang.org/docs/strformat.html

---

• Cleversn (orginal) [2023-10-17T22:19:52+02:00] view original

  Thanks all; I liked the .join method for now, but string formatting will also be useful in the future.

---

• dlesnoff (orginal) [2023-10-18T16:35:31+02:00] view original

  I wrote the solution with Araq's hint. It did not work for me with a procedure instead of a macro.

  import macros, winim
  
  let myRange = 0..99
  
  macro playAndWriteLN(audioFile: string; myStr: varargs[typed]): untyped =
    result = newStmtList()
    
    # Add PlaySound call to result
    let playStmt = quote do:
      PlaySound(`audioFile`, 0, SND_NOSTOP)
    result.add(playStmt)
    
    # Add echo call to result
    let echoStmt = newCall("echo")
    for s in myStr:
      echoStmt.add(s)
    result.add(echoStmt)
  
  playAndWriteLN("C:/winvox/Sound/Sortevox/So_sorte.wav", "The range is between ", myRange.a, " and ", myRange.b)
  Run

---

• shirleyquirk (orginal) [2023-10-18T17:47:14+02:00] view original

  A template is sufficient:

  import std/macros
  
  template playAndWriteLN(audioFile: string; myStr: varargs[typed]) =
    PlaySound(`audioFile`, 0, SND_NOSTOP)
    echo.unpackVarargs(myStr)
  Run

---