Mirror of forum.nim-lang.org

8859 :: Defer within async dispatch

• Neodim (orginal) [2022-02-01T13:02:03+01:00] view original

  Hi everybody,

  Just faced with strange thing:

  looks like defer statement does not work within async dispath, here is the code:

  
  proc get_data*(): Future[string] {.async.} =
    let DOWNLOAD_API_URL = "some HTTP address"
    try:
      let client = newAsyncHttpClient()
      defer: client.close()
      client.headers = newHttpHeaders({"Content-Type": "application/json"})
      let body = "some body"
      let resp = await client.request(DOWNLOAD_API_URL, httpMethod = HttpPost, body = $body)
      return await resp.body
    except Exception as e:
      return "Connection failed: " & e.msg
  
  discard WaitFor get_data()
  Run

  This code causes connection leak with CLOSE-WAIT status. Surely adding straight close.client() statement at the end of proc solves the problem, but whats wrong with defer?

---

• exelotl (orginal) [2022-02-01T13:19:03+01:00] view original

  Does it work if you put the client.close() in a finally: section at the end of the try..except?

  I've heard Araq say that defer is hard to maintain the past, so wouldn't be surprised if there are bugs with it - maybe it just doesn't work in closure iterators (the underlying mechanism used by async).

  With arc/orc you can implement a more robust defer in just a few lines of code, so maybe Nim 2.0 should just ditch the defer keyword and and replace it with a library function like this?

  type DeferCode = object
    f: proc()
  
  proc `=destroy`(d: var DeferCode) =
    d.f()
  
  template myDefer(body: untyped) =
    let d {.used.} = DeferCode(f: proc () = body)
  
  
  myDefer echo "bye 1"
  myDefer:
    echo "bye 2"
  
  echo "hi"
  
  # output:
  # hi
  # bye 2
  # bye 1
  Run

---

• Neodim (orginal) [2022-02-01T13:33:32+01:00] view original

  Heh, it should be in try section, not finally: the idea is if something wrong with local network it will cause an error with http.client making so it will be nothing to close finally - it will fall in a new error. I heard about to depreciate defer as I understand it was not done, at least compiler said nothing about it. Again, defer looks like a common and widely used pattern, for such case, I see no way it is canceled...

---

• exelotl (orginal) [2022-02-01T13:56:47+01:00] view original

  newAsyncHttpClient can't fail though, so I'm fairly certain you could do something like this:

  proc get_data*(): Future[string] {.async.} =
    let DOWNLOAD_API_URL = "some HTTP address"
    let client = newAsyncHttpClient()
    client.headers = newHttpHeaders({"Content-Type": "application/json"})
    let body = "some body"
    try:
      let resp = await client.request(DOWNLOAD_API_URL, httpMethod = HttpPost, body = body)
      return await resp.body
    except Exception as e:
      return "Connection failed: " & e.msg
    finally:
      client.close()
  
  discard waitFor get_data()
  Run

---