Mirror of forum.nim-lang.org

7381 :: memberProc macro

• chaemon (orginal) [2021-01-13T18:02:55+01:00] view original

  I made a following macro for which when a proc is called inside "classProc" block, insert a self argument and access these member variable by self.x. Now, I want to make the macro to be

  1. member variables(such as self.x) are changeable i.e. I want to insert "self: var S" instead of "self:S"
  2. accessible by only x instead of by self.x. (I believe this is possible by inserting "template x():auto = self.x" to proc body automatically. But I must get names of member variable compile time. It seems that "fields" function do such things. But I couldn't use it in macro statement. )

  Are there any way? Thanks!

  {.experimental.}
    
    import macros
    
    proc convertToMemberProc( procDefNode:NimNode, className:string ) =
      var formalParamsNode = procDefNode[3]
      formalParamsNode.expectKind( nnkFormalParams )
      var selfIdentNode = newIdentDefs( ident("self"), ident(className))
      formalParamsNode.insert( 1, selfIdentNode )
    
    type TraverseOp = enum Continue, Break, SkipChild, SkipSibling, Finished
    
    proc traverse(n: NimNode; action:proc(n:NimNode;parents:ref seq[NimNode]):TraverseOp; parents:ref seq[NimNode] = nil ):TraverseOp {.discardable.} =
      var parents = parents
      if parents == nil:
        parents.new
        parents.newseq( 0 )
      parents.add( n )
      
      for it in n.children:
        case action( it, parents )
        of Continue: discard
        of Break: return Break
        of SkipSibling: return SkipSibling
        of SkipChild: continue
        else: assert false
        
        case traverse( it, action, parents )
        of Break: return Break
        else: discard
      return Finished
    
    
    macro classproc(className:untyped,stmtList:untyped):untyped=
      var classNameStr = `$`(className)
      stmtList.traverse do (n:NimNode;parents:ref seq[NimNode]) -> TraverseOp:
        case n.kind
        of nnkProcDef, nnkMethodDef, nnkIteratorDef:
          n.convertToMemberProc( classNameStr )
        else: discard
      result = stmtList
    
    
    
    
    
    type S = object
      x:int
    
    classProc(S):
      proc f() =
        echo self.x
    
    var s = S(x:2021)
    s.f()
  Run

---

• ElegantBeef (orginal) [2021-01-14T10:52:57+01:00] view original

  As much as I dislike the emulating of classes in Nim here is usable version for only object types.

  {.experimental.}
  import macros
  
  proc convertToMemberProc( procDefNode:NimNode, className:string ) =
    var formalParamsNode = procDefNode[3]
    formalParamsNode.expectKind( nnkFormalParams )
    var selfIdentNode = newIdentDefs( ident("self"), ident(className))
    formalParamsNode.insert( 1, selfIdentNode )
  
  type TraverseOp = enum Continue, Break, SkipChild, SkipSibling, Finished
  
  proc traverse(n: NimNode; action:proc(n:NimNode;parents:ref seq[NimNode]):TraverseOp; parents:ref seq[NimNode] = nil ):TraverseOp {.discardable.} =
    var parents = parents
    if parents == nil:
      parents.new
      parents.newseq( 0 )
    parents.add( n )
    
    for it in n.children:
      case action( it, parents )
      of Continue: discard
      of Break: return Break
      of SkipSibling: return SkipSibling
      of SkipChild: continue
      else: assert false
      
      case traverse( it, action, parents )
      of Break: return Break
      else: discard
    return Finished
  
  
  macro classproc(className: typed,stmtList:untyped):untyped=
    var classNameStr = `$`(className)
    stmtList.traverse do (n:NimNode;parents:ref seq[NimNode]) -> TraverseOp:
      case n.kind
      of nnkProcDef, nnkMethodDef, nnkIteratorDef:
        n.convertToMemberProc( classNameStr )
      else: discard
    result = stmtList
    echo className.getImpl()[2][2].treeRepr
    for def in classname.getImpl()[2][2]:
      for ident in def[0..^3]:
        result.insert 0, quote do:
          template `ident`(): untyped = self.`ident`
    
    
    echo result.repr
  
  
  type S = object
    x:int
  
  classProc(S):
    proc f() =
      echo x
    
    var s = S(x:2021)
    s.f()
  Run

---

• chaemon (orginal) [2021-01-14T14:58:32+01:00] view original

  Thanks! I am reading the code. Is the following code example of member proc?

  https://github.com/beef331/constructor/blob/master/tests/objtest.nim

---

• ElegantBeef (orginal) [2021-01-14T19:44:57+01:00] view original

  No I was only showing the construct file as it works for distinct, ref, and normal objects.

---