Mirror of forum.nim-lang.org

13642 :: Is it possible to set an import path at compile time?

• hmf (orginal) [2026-01-09T17:57:36+01:00] view original

  Hello,

  I have something like this:

  
  import ../../funim_glfw/src/glfw3_api
  import ../../funim_glfw/src/mods/utils
  import ../../funim_glfw/src/mods/debug
  import ../../funim_glfw/src/mods/obj_parser
  import ../../funim_glfw/src/mods/shapes
  Run

  I would like to have something like:

  
  const GLFW_ROOT = "../funim_glfw/src/glfw"
  import &"../{GLFW_ROOT}/glfw3_api"
  Run

  Later I would also like to set these paths in a Nim file and include that at the start. This seems to work with pragmas (.compile.), but the import seems to consume the raw string.

  If not possible, any other way to do a similar thing?

  TIA

---

• arnetheduck (orginal) [2026-01-09T18:58:38+01:00] view original

  
  import macros
  macro myimport(v: static string) =
    let mi = ident v
    quote do:
      import `mi`
  
  myimport "tables"
  Run

  a macro works, though there might be better ways ;)

---

• hmf (orginal) [2026-01-09T19:51:35+01:00] view original

  Nice! Seems to be exactly what I need.

  Thank you.

---

• Araq (orginal) [2026-01-09T20:44:36+01:00] view original

  Uh oh that's a terrible idea for IC. :P

---

• arnetheduck (orginal) [2026-01-09T21:43:02+01:00] view original

  maybe it's ic that is a terrible idea ¯_(ツ)_/¯

---

• Araq (orginal) [2026-01-09T23:32:49+01:00] view original

  Throwing away parallel&incremental builds just so that you can save a <tab> press thanks to AI ... Sure, sure...

---

• ASVI (orginal) [2026-01-10T00:04:25+01:00] view original

  
  import ../../funim_glfw/src/[
    glfw3_api,
    mods/utils, mods/debug,
    mods/obj_parser, shapes]
  Run

---

• mig (orginal) [2026-01-10T00:06:35+01:00] view original

  isn't this just --path:"../funim_glfw/src/glfw" in config.nims - similarly --passC:"-I<dir>" for C header/source files ?

---

• hmf (orginal) [2026-01-10T09:28:35+01:00] view original

  Wasn't ware of this. Reconsidering.

---

• hmf (orginal) [2026-01-10T09:36:15+01:00] view original

  Good to know, was not aware of this. But I want something were I can share the lib source path among imports and pragmas.

---

• hmf (orginal) [2026-01-10T09:46:35+01:00] view original

  This seem doable. If I can manipulate the paths in the script, then the setup will require a single change in the root path. Maybe even make this a module that can be imported (same code as planned for arnetheduck's solution). Looking into it.

---

• hmf (orginal) [2026-01-10T09:51:28+01:00] view original

  Just an additional note in case someone else goes this root (irrespective of breaking parallel and incremental compilation): use an untyped parameter. This does not require the use of ident and the myimport need not use quotes.

  Still think it is interesting one can do this in Nim.

---

• hmf (orginal) [2026-01-10T17:40:04+01:00] view original

  Update - final solution: config.nims:

  
  const GLFW_ROOT = "../funim_glfw/src"
  
  switch("path", GLFW_ROOT)
  switch("passC", &"-I{GLFW_ROOT}/glad/include")
  switch("compile", &"{GLFW_ROOT}/glad/src/gl.c")
  switch("passL", &"`pkg-config --static --libs glfw3` -L{GLFW_ROOT}/glfw/build/src/")
  Run

  And the code just uses:

  
  import glfw3_api
  import utils
  import debug
  import obj_parser
  import shapes
  Run

  Thanks for the help.

---

• arnetheduck (orginal) [2026-01-10T18:01:08+01:00] view original

  Update - final solution

  Keep in mind that if you publish your code as a library, others will not be loading your config.nims.

---

• janAkali (orginal) [2026-01-11T04:59:14+01:00] view original

  Keep in mind that if you publish your code as a library, others will not be loading your config.nims

  You can put pragmas at the start of your main file:

  
  import std/strformat
  const GLFW_ROOT = "../funim_glfw/src"
  
  {.passc: &"-I{GLFW_ROOT}/glad/include".}
  {.compile: &"{GLFW_ROOT}/glad/src/gl.c".}
  {.passl: &"`pkg-config --static --libs glfw3` -L{GLFW_ROOT}/glfw/build/src/".}
  Run

  or even:

  
  import std/strformat
  const GLFW_ROOT = "../funim_glfw/src"
  
  {.passc: &"-I{GLFW_ROOT}/glad/include".}
  {.compile: &"{GLFW_ROOT}/glad/src/gl.c".}
  {.passl: gorge("pkg-config --static --libs glfw3") & &" -L{GLFW_ROOT}/glfw/build/src/".}
  Run

  https://nim-lang.org/docs/manual.html#implementation-specific-pragmas-compile-pragma

---

• hmf (orginal) [2026-01-11T12:44:10+01:00] view original

  Had not though of that. But the lib user will always have to know what paths and pragmas to use in there apps. Maybe documenting this is enough. Will cross that bridge if and when I get there.

---

• hmf (orginal) [2026-01-11T12:49:14+01:00] view original

  That was my initial solution, but I wanted a single place were to set this up (specifically the GLFW_ROOT path). Right now I copy the config.nim to a new project and change it as needed.

  Now that I think of it, it would be nice if compiling a library could pull in some of its configurations automatically for client use.

---