Mirror of forum.nim-lang.org

10823 :: Are generic procedures default to `mixin`?

• sls1005 (orginal) [2024-01-01T11:42:10+01:00] view original

  For example,

  type X = object
    i: int
  
  proc f[T](x: T): string =
    echo $x
  
  proc `$`(x: X): string =
    $(x.i)
  
  f(X())
  Run

  prints 0.

  type X = object
    i: int
  
  proc f(x: X): string =
    echo $x
  
  proc `$`(x: X): string =
    $(x.i)
  
  f(X())
  Run

  prints (i:0).

  But I'm not sure if a generic proc will bind every symbol late.

---

• ElegantBeef (orginal) [2024-01-01T22:15:45+01:00] view original

  No, only overloaded symbols are defaulted to open(mixin), non overloaded are bound to the symbol. This can be seen with a simple macro:

  import std/macros
  
  proc printSymChoice(impl: NimNode) =
    for n in impl:
      case n.kind
      of nnkOpenSymChoice:
        hint("Opened: " & $n[0], n)
      of nnkClosedSymChoice:
        hint("Closed: " & $n[0], n)
      else:
        printSymChoice(n)
  
  
  macro printSymChoices(t: typed): untyped =
    printSymChoice(t.getImpl())
  
  proc myProc(i: auto) = discard
  
  proc doThing[T](a: T) =
    myProc(a)
  
  printSymChoices(doThing)
  
  proc doX(a: int) = discard
  proc doX(a: float) = discard
  
  proc myProc(f: float) = discard
  
  proc doOtherThing[T](a: T) =
    bind doX
    myProc(a)
    doX(a)
  
  printSymChoices(doOtherThing)
    
  Run

---