Mirror of forum.nim-lang.org

8928 :: Macro fails with `got: <S> but expected <T>`

• tsojtsoj (orginal) [2022-02-17T16:23:24+01:00] view original

  The following macro fails, and I don't understand why. here on the Nim playground

  import macros
  
  type MyModel[T] = object
      discard
  
  macro network*(): untyped =
      
      let underlyingTypeSymbol = ident"WHAT"
      
      var params = @[
          newNimNode(nnkBracketExpr).add(
              ident"MyModel",
              underlyingTypeSymbol
          ),
          newIdentDefs(
              ident"a",
              newNimNode(nnkBracketExpr).add(
                  ident"MyModel",
                  underlyingTypeSymbol
              )
          )
      ]
      
      result = newProc(
          name = ident"init",
          params = params
      )
      # GenericParams
      result[2] = newNimNode(nnkGenericParams).add(
          newIdentDefs(
              underlyingTypeSymbol,
              newEmptyNode()
          )
      )
      
      echo toStrLit(result)
  
  
  network()
  
  Run

  The macro is supposed to create a function like this:

  proc init[WHAT](a: MyModel[WHAT]): MyModel[WHAT] = discard
  Run

  But I get an error when compiling:

  
  Hint: used config file '/home/tsoj/.choosenim/toolchains/nim-1.6.4/config/nim.cfg' [Conf]
  Hint: used config file '/home/tsoj/.choosenim/toolchains/nim-1.6.4/config/config.nims' [Conf]
  ...........................................................
  proc init[WHAT](a: MyModel[WHAT]): MyModel[WHAT] =
  
  /tmp/testtest.nim(39, 8) template/generic instantiation of `network` from here
  /tmp/testtest.nim(11, 19) Error: cannot instantiate MyModel [type declared in /tmp/testtest.nim(3, 6)]
  got: <WHAT>
  but expected: <T>
  Run

  Did I mess something up or is this a compiler bug?

---

• jyapayne (orginal) [2022-02-17T19:56:59+01:00] view original

  It might be a bug because this works:

  import macros
  
  type MyModel[T] = object
      discard
  
  macro network*(): untyped =
    result = quote do:
      proc init[WHAT](a: MyModel[WHAT]): MyModel[WHAT] =
        discard
  
  
  network()
  
  echo init(MyModel[int]())
  Run

---

• DeletedUser (orginal) [2022-02-18T00:59:23+01:00] view original

  If you don't reuse the ident node and recreate it every time it works.

---

• tsojtsoj (orginal) [2022-02-18T02:08:45+01:00] view original

  Yes, this is what I chose to use as a workaround. Because in my real program the ident"S" is instead a generated unique symbol, I need to basically create a new ident by converting the generated symbol to a string literal and then using that as ident strVal.

---

• DeletedUser (orginal) [2022-02-18T04:27:58+01:00] view original

  It works if you use copy too.

  import macros
  
  type MyModel[T] = object
      discard
  
  macro network*(): untyped =
      
      let underlyingTypeSymbol = genSym(nskGenericParam, "WHAT")
      
      var params = @[
          newNimNode(nnkBracketExpr).add(
              ident"MyModel",
              copy underlyingTypeSymbol
          ),
          newIdentDefs(
              ident"a",
              newNimNode(nnkBracketExpr).add(
                  ident"MyModel",
                  copy underlyingTypeSymbol
              )
          )
      ]
      
      result = newProc(
          name = ident"init",
          params = params
      )
      # GenericParams
      result[2] = newNimNode(nnkGenericParams).add(
          newIdentDefs(
              copy underlyingTypeSymbol,
              newEmptyNode()
          )
      )
  
  
  network()
  discard MyModel[int]().init
  Run

---