Mirror of forum.nim-lang.org

4323 :: Is there a handy way to declare Rune literals?

• vsajip (orginal) [2018-10-19T18:53:54+02:00] view original

  If one is looking through Unicode text and wants to compare a given rune with some literal value like '.' or ',', is there any easy way of declaring ASCII char values as Rune literals so that they can be compared more readably than doing if some_rune == Rune('.') or similar? Something like Python 2's u'foo' prefix? I couldn't see anything in the tutorials about this. Alternatively, something like Python's from __future__ import unicode_literals, only that applies to entire modules and one might want to just enable it locally for a single proc or a block within a proc.

---

• Tiberium (orginal) [2018-10-19T19:08:48+02:00] view original

  Since Unicode contains all ASCII characters you can easily do that:

  import unicode
  
  let my_rune = Rune(ord('.'))
  echo my_rune
  Run

---

• vsajip (orginal) [2018-10-19T19:13:41+02:00] view original

  Well, I could just do Rune('.') which also works, without the need for ord(), but I'm looking to see if there's something more compact like u'.' or similar.

---

• DeletedUser (orginal) [2018-10-19T20:57:30+02:00] view original

  You can partly achieve this for double quoted strings with the raw string call syntax:

  import unicode
  
  template u(s: string): seq[Rune] =
    toRunes(s)
  
  echo u"abcd"
  Run

  I don't think you can do the same with single quoted strings, however you can define a very simple macro that turns it into a character literal.

  import unicode, macros
  
  macro uc(s: string{lit}): untyped =
    result = newCall(bindSym("Rune"), newLit(s.strVal[0]))
  
  echo uc"a"
  Run

  If you want your character literal to be able to be more than 1 ASCII character you can use compile time evaluation:

  import unicode, macros
  
  macro uc(s: string{lit}): untyped =
    result = newCall(bindSym("Rune"), newLit(runeAt(s.strVal, 0).int16))
  
  echo uc"漢"
  Run

---

• vsajip (orginal) [2018-10-20T09:50:53+02:00] view original

  Those are very handy idioms to know, thanks!

---

• doofenstein (orginal) [2018-10-21T00:16:42+02:00] view original

  instead of using a macro, you could also use a template, which is imho the better way, since it's a less powerful construct and easier readable:

  import unicode
  
  template uc(s: static[string]): Rune =
    const runeVal = runeAt(s, 0)
    runeVal
  Run

---