Mirror of forum.nim-lang.org

3547 :: Import module by name / absolute path

• c0ntribut0r (orginal) [2018-02-14T15:59:26+01:00] view original

  Consider I have these modules which define the same functions (only implementation differs):

  
  -math_precise.nim
  -math_optimal.nim
  -math_fast.nim
  Run

  Now I want to include them based on compile-time option.

  I know I can use

  const math {.strdefine.}: string = "precise"  # default value
  when math == "precise":  # <-- here I hardcode possible values
    import math_precise
  elif math == "fast":
    import math_fast
  Run

  And then

  
  nim c -d:math:fast
  Run

  1) What if I don't want to hardcode modules names and just import by name? Like

  const math {.strdefine.}: string = "precise"  # default value
  import "math_" & math  # <-- Error: invalid module name :( I guess I should play with macros?
  Run

  2) Also, is there any way to import module by absolute location?

  import /tmp/math_superfast
  Run

  3. Will things work if I use "include" instead of "import"? (I know the difference between them)
  4. How to set up custom avatar on this forum? :)

---

• Araq (orginal) [2018-02-14T16:05:03+01:00] view original

  2. import "/tmp/math_superfast" (with the quotes) works.
  3. You can use a macro for that, yes.

  3. Certainly.
  4. register at gravatar

---

• c0ntribut0r (orginal) [2018-02-15T13:36:44+01:00] view original

  That's why I like nim! Got a reply on my questions in 5 minutes from Araq! :) Thank you

---

• Udiknedormin (orginal) [2018-02-20T12:21:46+01:00] view original

  @Araq How can I do it with macros? getImpl returns the const's default value, not the strdefined one:

  import macros
  
  const module {.strdefine.}: string = "math"
  
  macro importconst(name: string): untyped =
    let value = name.symbol.getImpl
    echo "variable name: ", name.repr
    echo "default value: ", $value
    result = newNimNode(nnkImportStmt).add(value)
  
  static:
    echo "actual  value: ", module
    importconst(module)
  
  # for -d:module=ropes it prints:
  #   variable name: module
  #   default value: math
  #   Hint: math [Processing]
  #   actual  value: ropes
  Run

  I encountered this problem a few times before, actually. What we need here is a routine input of which are normal variables but output of which is code. But we only have code2code (macros) and data2data (procs)...

---

• guibar (orginal) [2018-02-20T18:00:35+01:00] view original

  @Udiknedormin Here you can use static types that passes data to macros instead of a NimNode

  import macros
  
  const module {.strdefine.}: string = "math"
  
  macro importconst(name: static[string]): untyped =
    #let value = name.symbol.getImpl
    #echo "variable name: ", name.repr
    #echo "default value: ", $value
    result = newNimNode(nnkImportStmt).add(newIdentNode(name))
  
  static:
    echo "actual  value: ", module
  importconst(module)
  Run

---

• Udiknedormin (orginal) [2018-02-22T13:00:14+01:00] view original

  @guibar Thank you, guibar, I forgot I need a static[T] to change macros' semantics. I haven't used that for some time now.

---

• c0ntribut0r (orginal) [2018-03-02T16:01:50+01:00] view original

  Same for import as statement, if anyone cares:

  import macros
  
  macro importString(path: static[string], alias: static[string]): untyped =
    result = newNimNode(nnkImportStmt).add(
      newNimNode(nnkInfix).add(
        newIdentNode("as")
      ).add(
        newIdentNode(path)
      ).add(
        newIdentNode(alias)
      )
    )
  
  importString("strutils", alias="su")
  Run

---