Mirror of forum.nim-lang.org

2923 :: Checking in macro if proc has side effects or not

• cdome (orginal) [2017-04-21T16:27:08+02:00] view original

  Hi,

  Nim has a wonderful feature of the sideEffect tracking and I know one can annotate the proc with noSideEffect pragma to enforce no side effects constraint.

  In my case proc is not annotated, but I still would like to know whether particular function has side effects or not. Mainly to know if it is safe to incrementalize the calculation and it includes memoization.

  proc p1(a, b: int): int =
    result = 2 * a + b
  
  proc p2(a, b: int): int =
    echo "AAAA"
    result = b
  
  macro hasSideEffect(procName: typed): bool =
    ... # not clear how to implement
  
  
  hasSideEffect(p1) # returns compile time false
  hasSideEffect(p2) # returns compile time true
  Run

---

• Krux02 (orginal) [2017-04-21T17:28:22+02:00] view original

  Well I don't know if there is something built into the language to do that simply. But you can jump to the definition of the proc symbol and get the implementation. You could add the noSideffects pragma to the function and then test if that ast still compiles with system.compiles.

---

• cdome (orginal) [2017-04-21T18:06:35+02:00] view original

  Thanks Krux02,

  Feels like I am getting close:

  import macros
  
  proc clean(a, b: int) : int =
    result = 2 * a  + b
  
  macro hasNoSideEffects(p : typed) : bool =
    var procDef = getImpl(p.symbol)
    addPragma(procDef, newIdentNode("noSideEffect"))  # commenting this line has no effect, compiles() will return false anyway
    result = newCall(newIdentNode("compiles"), procDef)
    echo treeRepr(result)
  
  echo hasNoSideEffects(clean)
  Run

  The following code returns false all the time, I can't make compiles() to work on proc definitions

---

• Krux02 (orginal) [2017-04-21T18:42:16+02:00] view original

  well, when it doesn't work it is probably a Nim bug. Create an issue.

---

• stisa (orginal) [2017-04-21T19:13:11+02:00] view original

  Something like this?

  import macros
  
  proc clean(a, b: int) : int =
    result = 2 * a  + b
  
  proc dirty(a,b:int): int =
    echo "dirty"
    3
  
  macro hasNoSideEffects(p : typed) : untyped =
    result = newCall("compiles", newNimNode(nnkProcDef))
    let frm = p.symbol.getImpl
    var i = 0
    # frm has an additional result node at the end, this ugly loop
    # is to construct our procDef without altering the original proc.
    while i < frm.len-1:
      if i == frm.len-1: break
      result[1].add(frm[i])
      inc i
    addPragma(result[1], newIdentNode("noSideEffect"))
  
  echo hasNoSideEffects(clean) # true
  echo hasNoSideEffects(dirty) # false
  Run

  As NimNodes are ref types, I don't think you should change the ones returned from getImpl directly ( I may be wrong though ).

  ( There are probably better ways to get all childs except the last, but I can't seem to find them. )

  When dealing with macros, it's usually useful to compare the ast you generate with the ast printed by dumpTree, eg:

  import macros
  dumpTree:
    proc clean(a, b: int) : int {.noSideEffect.} =
      result = 2 * a  + b
  Run

---

• cdome (orginal) [2017-04-21T19:16:29+02:00] view original

  I have nailed down the reason why compiles() failed:

  • procDef body was full of resolved symbols, so it has to be piped through parseStmt(repr(...))

  The following works:

  macro hasNoSideEffects(p : typed) : bool =
    var procDef = getImpl(p.symbol)
    addPragma(procDef, newIdentNode("noSideEffect"))
    result = newCall(newIdentNode("compiles"), parseStmt(repr(procDef)))
  Run

  Still I think it would more convenient to have a standard function in macros module that will expose tags and effects of the procs.

---

• Krux02 (orginal) [2017-04-23T20:01:30+02:00] view original

  i can also imagine that the cause of compiles to fail is, that you have a double definition of the same function when you try to compile the exact same function again. So I think it would be sufficient to replace the symbolf the function with a new identifier.

---