Mirror of forum.nim-lang.org

2292 :: is this a bug or not?

• nimer (orginal) [2016-05-31T15:59:10+02:00] view original

  hi, guys,

  
  var s:string="a\0b\0c"
  echo s
  Run

  I just get "a", while the left part, I mean "b" and "c', is missing. The similar situation is in seq[string] or seq[char]. I guess it's probably because the first '0' is taken as the end of the string. But is there any way to get around and print the whole string like "a b c"?

---

• OderWat (orginal) [2016-05-31T17:27:47+02:00] view original

  You could replace the 0 with something printable or remove them:

  
  import strutils
  
  var s = "a\0b\0c"
  
  echo s.replace("\0", "\\0")
  echo s.replace("\0", "")
  echo s.repr
  
  for c in s: write(stdout, c)
  write(stdout, "\n")
  
  proc stringToHex(s: string): string =
    result = ""
    for o,c in s:
      if o != 0:
        result.add ' '
      result.add c.int.toHex(2)
  
  echo s.stringToHex
  Run

  Run It

---

• nimer (orginal) [2016-05-31T20:08:02+02:00] view original

  @OderWat OK, your solution works. And I think it should be fixed in the source code of nim.

---

• Araq (orginal) [2016-05-31T20:13:21+02:00] view original

  It's not that simple to fix without rewriting the IO layer so that 'echo' remains thread-safe.

  https://github.com/nim-lang/Nim/issues/1137

---

• nimer (orginal) [2016-05-31T21:13:18+02:00] view original

  @Araq

  Challenges are to be overcome by the brilliants. @Araq, you're one of them. We all expect nim to be better. :P

---

• OderWat (orginal) [2016-05-31T22:35:16+02:00] view original

  What about:

  proc echoBinSafe*(args: varargs[string, `$`]) =
    proc fwrite (buf: cstring, size, n: int, f: File) {.importc, noDecl.}
    proc flockfile(f: File) {.importc, noDecl.}
    proc funlockfile(f: File) {.importc, noDecl.}
    flockfile(stdout)
    for s in args:
      fwrite(s.cstring, s.len, 1, stdout)
    const linefeed = "\n" # can be 1 or more chars
    fwrite(linefeed.cstring, linefeed.len, 1, stdout)
    funlockfile(stdout)
  
  var s = "a\0b\0c"
  echoBinSafe s, "Hello World!"
  echo "done"
  Run

  Afaik this is thread safe and does not alloc ram.. and handles newlines. I guess it will not work on windows though. But who uses windows anyway (little joke).

---