Mirror of forum.nim-lang.org

2051 :: Load nim module dynamically?

• shaunc (orginal) [2016-02-17T09:08:42+01:00] view original

  Is it possible to load a nim dylib dynamically from another module?

  As a test, I have foo:

  proc getDefn() : int {.exportc cdecl.} =
    return 1
  Run

  and run nim c --app:lib foo.nim.

  In 2nd module I have

  import dynlib
  type
    InitProc = (proc() {.cdecl.})
    GetDefn = (proc(): int {.cdecl.})
  
  let fn = "libfoo.dylib"
  let libHandle = loadLib(fn)
  let init = cast[InitProc]( checkedSymAddr(libHandle, "NimMain"))
  init()
  let test = cast[GetDefn](checkedSymAddr(libHandle, "getDefn")
  echo $test()
  Run

  But it fails with SIGBUS: Illegal storage access. (Attempt to read from nil?) on the last statement.

---

• def (orginal) [2016-02-17T14:07:07+01:00] view original

  Works fine here on Linux (using GCC and Clang and with libfoo.so of course), might be a Mac OSX specific problem.

---

• shaunc (orginal) [2016-02-17T16:18:18+01:00] view original

  @def ... thanks ... hmm: are you using the same pragmas I have?

---

• def (orginal) [2016-02-17T16:49:33+01:00] view original

  Yes, I used your exact code, only changed libfoo.dylib to libfoo.so and fixed the missing bracket in the second last line.

---

• OderWat (orginal) [2016-02-17T17:55:25+01:00] view original

  Here example code which I use on OSX:

  # plugin.nim
  
  var data = 0
  
  {.push dynlib exportc.}
  
  proc setup*(num:int) =
    data = num
    echo "Plugin Setup!"
  
  proc getData*: int = data
  
  {.pop.}
  Run

  # plugin.nim.cfg
  app:lib
  Run

  # app.nim
  
  import dynlib
  
  type
    SetupProc = proc(num:int) {.nimcall.}
    GetDataProc = proc(): int {.nimcall.}
  
  proc testPlugin(path:string) =
    let lib = loadLib(path)
    if lib != nil:
      let setupAddr = lib.symAddr("setup")
      let getDataAddr = lib.symAddr("getData")
      
      if setupAddr != nil and getDataAddr != nil:
        let setup = cast[SetupProc](setupAddr)
        let getData = cast[GetDataProc](getDataAddr)
        
        setup(123)
        echo "Plugin Data: ", getData()
      
      unloadLib(lib)
  
  when defined(macosx):
    testPlugin("./libplugin.dylib") # osx path
  else:
    testPlugin("./libplugin.so") # unix path
  Run

---

• McDepp (orginal) [2016-02-17T20:32:38+01:00] view original

  I fixed the missing bracket in the second last line, but I don't modfy the code. It works under MacOS X.

---

• shaunc (orginal) [2016-02-19T20:58:43+01:00] view original

  Ok thanks, everyone! My example was extracted from a larger code block, and the function I was trying to call was being spit out by a macro; it turned out I hadn't wrapped everything I needed to in the right pragmas. Now I have it working.

  What is the right way to do this portably, btw? Should I use cdecl, or nimcall as @OderWat suggests? Or does it not matter as long as I am consistent? I see there is a DynlibFormat constant in os ... presumably this is what I should use to avoid a case stmt?

---