Mirror of forum.nim-lang.org

1551 :: Asyncnet example

• andrea (orginal) [2015-08-17T22:24:14+02:00] view original

  I am trying to run the example from the asyncnet documentation. I have just modified it to print whatever I receive for debugging.

  import asyncnet, asyncdispatch
  
  var clients {.threadvar.}: seq[AsyncSocket]
  
  proc processClient(client: AsyncSocket) {.async.} =
    while true:
      let line = await client.recvLine()
      echo "Received: " & line & "!"
      for c in clients:
        await c.send(line & "\c\L")
  
  proc serve() {.async.} =
    clients = @[]
    var server = newAsyncSocket()
    server.bindAddr(Port(12345))
    server.listen()
    
    while true:
      let client = await server.accept()
      clients.add client
      
      asyncCheck processClient(client)
  
  asyncCheck serve()
  runForever()
  Run

  I can connect it with telnet or python, but as soon as a client disconnect I see printed a never-ending stream of empty lines Received: !

  Is this expected? Am I doing something wrong?

---

• Eedee (orginal) [2015-08-17T23:01:58+02:00] view original

  Code, is fine but when socket is closed, the recv or recvLine will keep returning "" forever. So if you recv "" from the socket it means, that it has been closed and you should stop trying to recv from it.

  Here is the fixed version:

  
  import asyncnet, asyncdispatch
  
  var clients {.threadvar.}: seq[AsyncSocket]
  
  proc processClient(client: AsyncSocket) {.async.} =
    while true:
      let line = await client.recvLine()
      if line != "":
        echo "Received: " & line & "!"
        for c in clients:
          await c.send(line & "\c\L")
      else:
        #It seems sock received "", this it means connection has been closed.
        client.close()#You should also close and remove the socket from the list
        for i, c in clients:
          if c == client:
            clients.del(i)
            break
        echo("Client has left the server")
        break
  
  proc serve() {.async.} =
    clients = @[]
    var server = newAsyncSocket()
    server.bindAddr(Port(12345))
    server.listen()
    
    while true:
      let client = await server.accept()
      clients.add client
      
      asyncCheck processClient(client)
  
  asyncCheck serve()
  runForever()
  Run

---

• andrea (orginal) [2015-08-18T11:30:40+02:00] view original

  Thank you, that works! Now I have a different issue. I tried to write a simple client

  import asyncnet, asyncdispatch
  
  proc main() {.async.} =
    var client = newAsyncSocket()
    await client.connect("localhost", Port(12346))
    
    await client.send("Hello\r\L")
    let response = await client.recvLine()
    echo "Received: " & response & "!"
  
  waitFor main()
  Run

  and it works fine. If I change this to

  import asyncnet, asyncdispatch
  
  proc main() {.async.} =
    var client = newAsyncSocket()
    await client.connect("localhost", Port(12346))
    
    for s in ["Hi from the client", "This is Nim speaking"]:
      echo "about to send " & s
      await client.send(s & "\r\L")
      let response = await client.recvLine()
      echo "Received: " & response & "!"
  
  waitFor main()
  Run

  suddenly the client fails with SIGSEGV: Illegal storage access. (Attempt to read from nil?).

  I guess the memory for the strings may be garbage collected, since it seems to work with an array of ints, but I am not sure. What is the interaction between async procs and garbage collection?

---