Mirror of forum.nim-lang.org

11624 :: find field value object in seq and declared object in seq

• ingo (orginal) [2024-05-20T18:27:22+02:00] view original

  How does one find out whether a field in an object in an array exists? The commented out echo declared(c1.content[0].thing) errors.

  How do I find whether a value in a field of an object in an array exists using a proc, or template? The commented out code shows my failure.

  type
    Box = object
      thing: string
      food: bool
    
    Container = object
      content: seq[Box]
  
  var c1 = Container(
    content: @[
      Box(thing: "cake", food: true),
      Box(thing: "truck", food: false),
      Box(thing: "black puddin'", food: true),
      Box(thing: "dandelion", food: true)
    ]
  )
  
  echo type c1
  echo type c1.content
  echo type c1.content[0]
  echo type c1.content[0].thing
  echo declared(c1.content)
  #echo declared(c1.content[0].thing)
  
  var found = 0
  let item = false
  for obj in items(c1.content):
    if obj.food == item:
      echo found
    inc(found)
  
  #proc findInObjSeq*[T, S, P](a: T, field: P, item: S): int {.inline.} =
  #  result = 0
  #  for obj in items(a):
  #    if obj.field == item: return
  #    inc(result)
  #  result = -1
  #
  #echo findInObjSeq(c1, food, true)
  
  Run

---

• janAkali (orginal) [2024-05-20T18:52:09+02:00] view original

  From your example it seems that you want to count quantity of specified items in seq. You can do this easily with sequtils.countIt:

  import std/sequtils
  echo c1.content.countIt(it.food == true) # 3
  Run

  If you don't need a count and only want to check if item is present - use sequtils.anyIt:

  import std/sequtils
  echo c1.content.anyIt(it.food == true) # true
  Run

---

• Isofruit (orginal) [2024-05-20T18:58:46+02:00] view original

  Not entirely sure what exactly you want findInObjSeq to do. Is this supposed to return you a count? An Index? An instance from the list?

  Either way, if you want to get past this entirely without macros you will need to make use of the when keyword instead of "if". And also the fieldpairs iterator.

  When is like an if-check at compiletime, if you pass the code within the when-block gets compiled into the binary, if not it gets excluded.

  proc findInObjSeq*[T, S](objects: openArray[T], fieldName: static string, value: S): int =
    ## Returns index of first occurrence of an object in `objects` that has a field named `fieldName` with the value `value`.
    ## Returns -1 if no object in objects has a field named `fieldName`.
    ## Returns also -1 if the objects in `objects` contain a field with that name, but no value equaling `value`
    for index, obj in objects:
      for objFieldName, fieldValue in obj.fieldPairs:
        when objFieldName == fieldName:
          if fieldValue == value:
            return index
    
    return -1
  Run

  What this does is:

  1. Iterate at runtime over the various objects in whatever iterable type you have in objects
  2. Iterate at compileTime over the various fields in an object (it is at compileTime because .fieldPairs works that way) and do whatever operation inside the loop per field on T
  3. For each field you check at compiletime whether its name equals the name you defined at the start (so e.g. "food"). If that field has that name, then you want to perform the code within the when-block
  4. In the when-block check at run-time whether the value in that obj instance is equal to value. If it is, return thee index of that instance. If it isn't, move on.

---

• ingo (orginal) [2024-05-20T19:33:22+02:00] view original

  Thank you both. Enough to fiddle with. The goal is to find the index of the first occurrence of Box(food: value), if at all. Like seq.find(value)

  Cheers.

---