Mirror of forum.nim-lang.org

10204 :: Get cursor position in terminal

• jojocoding (orginal) [2023-05-18T17:09:15+02:00] view original

  I am working on a project in which I use a while true: getch() loop to handle user input. I have some code to handle backspace, but currently it is very buggy when you try to backspace onto the previous line. Is there any way to get the position of the cursor in the terminal (only the X pos is needed) to provide a fix for this issue? I could not find such functionality in the stdlib. I know I could use curses but would much rather find a solution that does not require external (non-Nim) libraries. I also would prefer a solution that does not require much rewriting, although I understand that may be necessary. I am using getch() instead of stdin.readLine which would handle this automatically because I need to be able to have the text the user types be colored while they type it, and I could not find a way besides getch() and stdout.styledWrite from std/terminal. Any suggestions?

---

• kobi (orginal) [2023-05-19T00:47:44+02:00] view original

  You can repaint the whole screen, and keep track of the text just in memory, a state object. (I think this is the solution you're looking for, but it's not very efficient on its own)

---

• xrfez1 (orginal) [2023-05-19T08:53:11+02:00] view original

  You can use a global counter to track input and setCursorPos(stdout, x, y) from it. Keeping track of the text in memory and setting the cursor position based on that text would give a better backspace experience. Probably. This shows how the counter could work, without any extra effort.

  import std/terminal
  
  type
    CarteseanCoordinate = tuple[x: int, y: int]
  
  # Global counter to track position
  var inputCounter: int
  
  proc getCursorPosition(): CarteseanCoordinate =
    ## Calculate the x,y coordinates from the global counter
    ## Returns a tuple(x: int, y: int)
    
    let lineLength = terminalWidth()
    
    if inputCounter <= lineLength: return (inputCounter, 0)
    result = (inputCounter mod lineLength, (inputCounter / lineLength).int)
  
  proc processBackspace() =
    ## Handle a backspace input and update global counters
    
    let cursorPosition = getCursorPosition()
    
    # Handle First Column
    if cursorPosition.x == 0:
      if cursorPosition.y == 0: return # Nothing to delete
      dec inputCounter
      stdout.setCursorPos(terminalWidth() - 1, cursorPosition.y - 1)
      write(stdout, ' ')
      stdout.setCursorPos(terminalWidth() - 1, cursorPosition.y - 1)
      return
    # Handle all other columns
    dec inputCounter
    stdout.setCursorPos(cursorPosition.x - 1, cursorPosition.y)
    write(stdout, ' ')
    stdout.setCursorPos(cursorPosition.x - 1, cursorPosition.y)
  
  proc processReturn() =
    ## Handle a return input and update global counters
    
    let cursorPosition = getCursorPosition()
    
    # Global counter to include all the empty space the terminal inserts
    inputCounter += terminalWidth() - cursorPosition.x
    write(stdout, '\n')
  
  proc processProblemInput(input: char): bool =
    ## Analyze input for special conditions
    
    if input == '\b':
      processBackspace()
      return true
    if input == '\r':
      processReturn()
      return true
  
  eraseScreen(stdout)
  stdout.setCursorPos(0,0)
  while true:
    let input = getch()
    if not processProblemInput(input):
      stdout.styledWrite(fgRed, $input)
      inc inputCounter
    showCursor(stdout)
  Run

---